---

第７回：マクロの登場人物の紹介（その６）

---

[ ← 前回の内容 | → 次回の内容 | 総目次 ]

---

節目次：

7.1　input 関数の動作について
7.2　if 文
7.3　if-else 文
演習問題

---

さて、前回作成したマクロはそれなりに動作はしますが、 例えば以下に挙げるような難点があります。


• 数字を入力するダイアログで [キャンセル] ボタンを押しても 処理が止まらない。
• ２番目の入力が０でないことを確認していないため、 マクロの処理の途中で「０による除算エラー」が発生する。

そこで、今回はこれらの難点を改善してみましょう。 前回のマクロのどこに改良を加えるかをあらかじめ示しておきます。



$num1 = input("１つめの数字を入力して下さい。","0");↓ // もし [キャンセル] ボタンが押されたらマクロを終了する↓ $num2 = input("２つめの数字を入力して下さい。\n(0 は入力しないこと！)","1");↓ // もし [キャンセル] ボタンが押されたらマクロを終了する↓ #num1 = val($num1);↓ #num2 = val($num2);↓ #wa = #num1 + #num2;↓ #sa = #num1 - #num2;↓ #seki = #num1 * #num2;↓ // もし #num2 が 0 だったら以下の計算は実行しない↓ // （その場合、#sho, #amari には 0 を代入することにする）↓ #sho = #num1 / #num2;↓ #amari = #num1 % #num2;↓ // もし #num2 が 0 だったら割り算と余りの結果は「計算不可能」と表示する↓ message $num1 + " ＋ " + $num2 + " ＝ " + str(#wa) + "\n" + ↓         $num1 + " − " + $num2 + " ＝ " + str(#sa) + "\n" + ↓         $num1 + " × " + $num2 + " ＝ " + str(#seki) + "\n" + ↓         $num1 + " ÷ " + $num2 + " ＝ " + str(#sho) + " 余り " + str(#amari);↓ [EOF]

7.1　input 関数の動作について

　[ ↑ 前節 | ↓ 次節 | 節目次 || ← 前回の内容 | → 次回の内容 | 総目次 ]

さて、まずは [キャンセル] ボタンでマクロが終了するように改良しましょう。 何はともあれ、


[キャンセル] ボタンが押されたことをマクロ中でどうやって認識するか？

が分かっていないとどうしようもないですね。 これは以下のようなマクロを実行してみると確認できます。



message input("","1");↓ [EOF]


このマクロを実行すると input 関数が返す文字列が そのままメッセージボックスに表示されます。 ではエディットボックスに何か文字が入力されている状態で [キャンセル] ボタンを押してみましょう。 すると、メッセージボックスには 何も文字が表示されていないことが分かります。 この結果から分かるように(*1)、 input 関数は [キャンセル] ボタンが押された場合は （エディットボックスに何かが入力されていても） ""（空文字列）を返します。

さて、[キャンセル] ボタンが押されたかどうかをマクロ中で認識するには 結局のところ


input 関数が返す文字列 （$num1, $num2）が ""（空文字列）に等しいかそうでないか

を確認すればよいことが分かったので(*2)、 次はその確認をマクロ中でどうやればいいかを考えましょう。



(*1)	細かいツッコミですが(^^;、 このままだと何も文字が返ってこなかったのか、 空白文字が返ってきたのか区別がつきませんね(^^;。 （→演習問題）
(*2)	またまた(^^;細かいツッコミですが、 これだけでは エディットボックスに何も入力していない状態で [ＯＫ] ボタンを押した場合 と区別ができていません。 なお、この２つのケースは関数を実行した後の result キーワードの値を調べれば区別できます。

7.2　if 文

　[ ↑ 前節 | ↓ 次節 | 節目次 || ← 前回の内容 | → 次回の内容 | 総目次 ]

まず、一般的にマクロ中で


「もし 〜 という条件が成り立てば … という処理を実行する」

という判断をするための典型的な書式を説明します。 それは以下のような形です。



if (条件) 条件が成り立つ場合に実行する処理


if という単語の後に、 丸括弧で条件を括ったものを書き、 その後に条件が成り立つ場合に実行したい処理を書きます。 今「条件」とか「処理」とかいった言葉で表現した部分には 実際には式やコマンドが入りますが、 それらの具体的な例を以下で紹介します。

最初の問題である 「$num1($num2) に入っている文字列が "" に等しければマクロを終了する」 を考えてみましょう。

まずマクロを（途中で）終了させるには endmacro コマンドを使います。 このコマンドを使えばマクロ中のどこででも処理を中止することができます。

そして「条件」に相当するのは 「$num1($num2) に入っている文字列が "" に等しい」ですが、 これを表すためには(文字列に対する)等価演算子「＝＝」を使います。 この演算子の両辺の文字列が 全角・半角の違いも考慮して一字一句同じ場合に限り、 条件が成り立つものと見なされます。

まとめると以下のようになります。



if ($num1 == "") endmacro;


…と、あっさり言い切ってしまいましたが(^^;、 この辺の話はほとんど決まり文句みたいなものなので、 あれこれ悩むよりはパターンを覚えてしまった方が早いです。

「＝＝」が出たついでに、 ２つの文字列が異なる場合に 条件が成り立つような演算子も紹介しておきましょう。 それは「！＝」というものですが、例えば以下のように使います。



$msg = input("メッセージを入力して下さい。","");↓ if ($msg != "") message $msg;↓


このマクロは入力された文字をメッセージボックスに表示するものですが、 [キャンセル] ボタンが押されたら （または何も入力せずに [ＯＫ] ボタンが押されたら） メッセージボックスを出さずに終了します。

さて、マクロの前半部分は結局



$num1 = input("１つめの数字を入力して下さい。","0");↓ if ($num1 == "") endmacro;↓ $num2 = input("２つめの数字を入力して下さい。","1");↓ if ($num2 == "") endmacro;↓


と修正すれば望み通りの動作をするようになるわけです。 ただ、[キャンセル] ボタンを押したらその時点でマクロが終了するのは ちょっと無愛想(^^;なので、マクロを終了する前に 「マクロを終了します」 というメッセージを表示してから終わるようにしてみましょう。 そこで、条件判断の部分を次のように書き換えたらどうなるでしょうか？



if ($num1 == "") message "マクロを終了します"; endmacro;


if (...) の後に２つの文を並べて書く事で、 条件が成り立つ場合に２つの文を実行させるつもりなのですが、 実際に実行してみると以下のような動作をしてしまいます。


• [キャンセル] ボタンを押すと「マクロを終了します」という メッセージを出してマクロが終了する（意図した動作）
• [ＯＫ] ボタンを押すといきなりマクロが終了する（あれ？？）

どうやら条件が成り立つかどうか （そして message コマンドが実行されるかどうか） に関わらず、 endmacro コマンドが実行されているようです？？ この予想が正しいことは、 上のマクロは以下のように書いても同じ、 ということを見れば明らかでしょう。



if ($num1 == "") message "マクロを終了します";↓ endmacro;


２つの文の区切り文字を 空白から改行に変えただけ（＝マクロの動作は変わらない）ですが、 何故上のような動作になったか納得しやすくなったと思います。 つまり、if (...) で、 条件によって実行するかしないかが決まるのは その直後の１つの文だけなのです。 では、条件が成り立った場合に 複数の文を実行することはできないのでしょうか？


もしそんなプログラミング言語があったら即刻使うのを止めましょう(^^;

と断言してもいいぐらい重要なことですが、ご安心下さい(^^;。 ちゃんとできるようになっています。 条件が成り立つ場合に複数の文を実行するには それらを "{" と "}" で囲みます。



if ($num1 == "") { message "マクロを終了します"; endmacro; }


このように中括弧で囲まれた部分を「ブロック」と呼びますが、 こうすると、条件が成り立つ場合にはブロックの中の文が全て実行され、 成り立たない場合にはブロック中の文が全て無視されるようになります。 ただ、普通はこういう書き方をせずに、 以下のように適当な所に改行や空白（またはタブ）を入れます(*1)。



if ($num1 == "") {↓     message "マクロを終了します";↓     endmacro;↓ }↓




(*1)	この空白や改行の位置に関しては （本当に(^^;）様々な流儀が存在しますが、 結局の所は自分が読みやすいと思った流儀を使うのが一番です。

7.3　if-else 文

　[ ↑ 前節 | ↓ 次節 | 節目次 || ← 前回の内容 | → 次回の内容 | 総目次 ]

さて、では次の #sho, #amari への代入を #num2 が０かそうでないかで変える部分にいきましょう。 今度は数値を別の数値（今の場合は０）と比較するわけですが、 この場合も文字列の場合に使った演算子「＝＝」や「！＝」が使えます （同じ記号ですが比較される対象が異なることに注意！）。 最初の例から以下のような書き方がすぐに思い浮かんだでしょうか？



#sho = 0;↓ #amari = 0;↓ if (#num2 != 0) {↓     #sho = #num1 / #num2;↓     #amari = #num1 % #num2;↓ }↓


#num2 の値が０なら、 #sho, #amari には 最初の２行で代入された値（＝０）がそのまま残りますが、 そうでなければ改めて商と余りが代入されます（ブロックの内部）。

最後の計算結果の表示を変える部分についても どうすればいいか明らかですね？(*1)



if (#num2 != 0)↓     message $num1 + " ＋ " + $num2 + " ＝ " + str(#wa) + "\n" + ↓             $num1 + " − " + $num2 + " ＝ " + str(#sa) + "\n" + ↓             $num1 + " × " + $num2 + " ＝ " + str(#seki) + "\n" + ↓             $num1 + " ÷ " + $num2 + " ＝ " + str(#sho) + " 余り " + str(#amari);↓ if (#num2 == 0)↓     message $num1 + " ＋ " + $num2 + " ＝ " + str(#wa) + "\n" + ↓             $num1 + " − " + $num2 + " ＝ " + str(#sa) + "\n" + ↓             $num1 + " × " + $num2 + " ＝ " + str(#seki) + "\n" + ↓             $num1 + " ÷ " + $num2 + " ＝ 計算不可能";↓


もちろんこれでも正しく動作するのですが、 どうも重複する部分が多いのが気になります。 しかも両者でどこが違うのかわかり難い、ということもあるので、 以下のようにしてみましょう。



// まず共通部分を変数 $msg に代入↓ $msg = $num1 + " ＋ " + $num2 + " ＝ " + str(#wa) + "\n" + ↓        $num1 + " − " + $num2 + " ＝ " + str(#sa) + "\n" + ↓        $num1 + " × " + $num2 + " ＝ " + str(#seki) + "\n" + ↓        $num1 + " ÷ " + $num2 + " ＝ ";↓ ↓ // 変数 #num2 が０かそうでないかで $msg に追加する文字列を変える↓ if (#num2 != 0) $msg = $msg + str(#sho) + " 余り " + str(#amari);↓ if (#num2 == 0) $msg = $msg + "計算不可能";↓ ↓ // 変数 $msg の内容を表示↓ message $msg;↓


これで大分見通しがよくなりましたが、 #num2 の値が０かそうでないかで追加する文字列を変える部分は、 よくよく考えると冗長な比較をしていることが分かります。 具体的には


１番目の if 文：

• #num2 が０でなければ 計算結果を $msg に追加する
• #num2 が０ならば何もしない

２番目の if 文：

• #num2 が０ならば 「計算不可能」を $msg に追加する
• #num2 が０でなければ何もしない

という処理になっていますが、 何もしない という所が２個所もあります。 これを一発で


• #num2 が０でなければ 計算結果を $msg に追加する
• そうでなければ（＝#num2 が０ならば） 「計算不可能」を $msg に追加する

とすることができないのでしょうか？ これもまた


そんなこともできないプログラミング言語はとっとと忘れましょう(^^;

といっても言い過ぎではないことなのですが、 そういう事ができる仕組みはしっかりと用意されていて、 以下のような形で書きます。



if (条件) 条件が成り立つ場合に実行する処理 else 条件が成り立たない場合に実行する処理


ここで、それぞれの処理は１つの文またはブロックからなります。 この書き方を使えば今の２つの if 文をまとめて



// 変数 #num2 が０かそうでないかで $msg に追加する文字列を変える↓ if (#num2 != 0) $msg = $msg + str(#sho) + " 余り " + str(#amari);↓ else $msg = $msg + "計算不可能";↓


とすることができます。

さて、最初のマクロが結局どうなったかをまとめて書き下しておきます。



$num1 = input("１つめの数字を入力して下さい。","0");↓ if ($num1 == "") {↓     // [キャンセル] ボタンが押された場合↓     message "マクロを終了します";↓     endmacro;↓ }↓ $num2 = input("２つめの数字を入力して下さい。","1");↓ if ($num2 == "") {↓     // [キャンセル] ボタンが押された場合↓     message "マクロを終了します";↓     endmacro;↓ }↓ #num1 = val($num1);↓ #num2 = val($num2);↓ #wa = #num1 + #num2;↓ #sa = #num1 - #num2;↓ #seki = #num1 * #num2;↓ // とりあえず #sho, #amari には 0 を代入する↓ #sho = 0;↓ #amari = 0;↓ if (#num2 != 0) {↓     // #num2 が０でなければ #sho, #amari にそれぞれ計算結果を代入↓     #sho = #num1 / #num2;↓     #amari = #num1 % #num2;↓ }↓ // まず共通部分を変数 $msg に代入↓ $msg = $num1 + " ＋ " + $num2 + " ＝ " + str(#wa) + "\n" + ↓        $num1 + " − " + $num2 + " ＝ " + str(#sa) + "\n" + ↓        $num1 + " × " + $num2 + " ＝ " + str(#seki) + "\n" + ↓        $num1 + " ÷ " + $num2 + " ＝ ";↓ // 変数 #num2 が０かそうでないかで $msg に追加する文字列を変える↓ if (#num2 != 0) $msg = $msg + str(#sho) + " 余り " + str(#amari);↓ else $msg = $msg + "計算不可能";↓ // 変数 $msg の内容を表示↓ message $msg;↓ [EOF]


これで、このマクロも少しは(^^;マシなものになったはずです。



(*1)	message コマンド以下４行を 中括弧で囲っていませんが、 これは（長いですが(^^;）１つの文 なので ブロックにする必要はありません。

演習問題

　[ ↑ 前節 | ↓ 次節 | 節目次 || ← 前回の内容 | → 次回の内容 | 総目次 ]

1. input 関数の返す文字列を メッセージボックスに表示するマクロを、 文字列が空白のみからなるものであっても 見た目にそれとわかるように改良せよ。
   （ヒント：文字列を "[" と "]" で囲んだものを表示させよ）



2. 変数 $str の中身が "" でなければ その文字列を現在のカーソル位置に挿入するマクロ（の一部分）を書け。



3. 前問で、$str の中身が "" だった場合は、 文字を入力するダイアログを表示して そこに入力された文字を挿入するようにせよ。 但し、[キャンセル] ボタンが押されるか何も入力されなければ マクロを終了するようにせよ。

---

[ ↑ 先頭に戻る || ← 前回の内容 | → 次回の内容 | 総目次 ]